/*****

	Ontology for KA-Community
	Version 0.991, October 8nd, 1997

	All classes in this ontology are sub-sub-classes of
	the top level class Root.

	update, 2000-02-14 MER
		adopted ontology extensions from the KA2-reseachrch-topic-work

*****/

/*****
	Firstly, the is-a hierarchy is presented,
	attribute definitions follow below.

	The is-a hierachy ensures attribute inheritance
	and subset relationship.

*****/


Root[].

Organization :: Root.
  Enterprise :: Organization.
  University :: Organization.
  Department :: Organization.
  Institute :: Organization.
  ResearchGroup :: Organization.

Person :: Root.
  Employee :: Person.
    AcademicStaff :: Employee.
      Researcher :: AcademicStaff.
        PhDStudent :: Researcher.
      Lecturer :: AcademicStaff.
    AdministrativeStaff :: Employee.
      Secretary :: AdministrativeStaff.
      TechnicalStaff :: AdministrativeStaff.
  Student :: Person.
    PhDStudent :: Student.

Publication :: Root.
  Book :: Publication.
  Article :: Publication.
    TechnicalReport :: Article.
    JournalArticle :: Article.
    ArticleInBook :: Article.
    ConferencePaper :: Article.
    WorkshopPaper :: Article.
  Journal:: Publication.
    SpecialIssue :: Journal.
  OnlinePublication :: Publication.

Project :: Root.
  ResearchProject :: Project.
  DevelopmentProject :: Project.
    SoftwareProject :: DevelopmentProject.

Event :: Root.
  Conference :: Event.
  Workshop :: Event.
  Activity :: Event.
  SpecialIssue :: Event.
  Meeting :: Event.

ResearchTopic :: Root.
  KAthroughMachineLearning :: ResearchTopic.
    Abduction :: KAthroughMachineLearning.
    CaseBaseReasoning :: KAthroughMachineLearning.
    CooperativeKnowledgeAcquisition :: KAthroughMachineLearning.
    KnowledgeBasedRefinement :: KAthroughMachineLearning.
    KnowledgeDiscoveryInDatasets :: KAthroughMachineLearning.
    DataMining :: KAthroughMachineLearning.
    LearningApprenticeSystems :: KAthroughMachineLearning.
    ReinforcementLearning :: KAthroughMachineLearning.
  Reuse :: ResearchTopic.
    Ontologies :: Reuse.
      TheoreticalFoundations :: Ontologies.
      SoftwareApplications :: Ontologies.
      Methodologies :: Ontologies.
    PSMs :: Reuse.
      PSMevaluation :: PSMs.
      PSMlibraries :: PSMs.
      PSMnotations :: PSMs.
      AutomatedPSMgeneration :: PSMs.
      SysiphusIIIexperiment :: PSMs.
      WebMediatedPSMselection :: PSMs.
    SoftwareReuse :: Reuse.
  SpecificationLanguages :: ResearchTopic.
    SpecificationMethodology :: SpecificationLanguages.
    SpecificationOfControlKnowledge :: SpecificationLanguages.
    SupportToolsForFormalMethods :: SpecificationLanguages.
    AutomatedCodeGenerationFromSpecification :: SpecificationLanguages.
    ExecutableSpecificationLanguages :: SpecificationLanguages.
  ValidationAndVerification :: ResearchTopic.
    AnomalyDetection :: ValidationANDVerification.
    AnomalyRepairAndKnowledgeRevision :: ValidationANDVerification.
    Formalisms :: ValidationANDVerification.
    Methodology :: ValidationANDVerification.
    VandVofMAS :: ValidationANDVerification.
  KnowledgeManagement :: ResearchTopic.
  KAmethodologies :: ResearchTopic.
  EvaluationOfKA :: ResearchTopic.
  KnowledgeElicitation :: ResearchTopic.

Product :: Root.


/*****
	Now the attribute definitions were added.
*****/


Root[	keyword =>> STRING].


/*****
	Organization
*****/

Organization[
	name =>> STRING;
	location =>> STRING;
	employs =>> Person;
	publishes =>> Publication;
	technicalReport =>> TechnicalReport;
	carriesOut =>> Project;
	develops =>> Product;
	finances =>> Project].

University[
	student =>> Student;
	hasParts =>> Department].

Department[
	hasParts =>> Institute].

Institute[
	hasParts =>> ResearchGroup].

ResearchGroup[
	member =>> Researcher;
	head =>> Employee].


/*****
	Person
*****/

Person[
	photo =>> STRING;
	firstName =>> STRING;
	middleInitial =>> STRING;
	lastName =>> STRING;
	name =>> STRING;
	address =>> STRING;
	email =>> STRING;
	phone =>> STRING;
	fax =>> STRING;
	publication =>> Publication;
	organizerOrChairOf =>> Event;
	memberOfPC =>> Event;
	editor =>> Publication].

Employee[
	affiliation =>> Organization;
	worksAtProject =>> Project;
	headOf =>> Project;
	headOfGroup =>> ResearchGroup].

AcademicStaff[
	supervises =>> PhDStudent].

Researcher[
	researchInterest =>> ResearchTopic;
	memberOf =>> ResearchGroup;
	cooperatesWith =>> Researcher].

Secretary[
	secretaryOf =>> ResearchGroup].

Student[studiesAt =>> University].

PhDStudent[
	supervisor =>> AcademicStaff].
	// Multiple inheritance from researcher and from student


/*****
	Publication
*****/

Publication[
	author =>> Person;
	title =>> STRING;
	year =>> NUMBER;
	abstract =>> STRING;
	onlineVersion =>> OnlinePublication;
	describesProject =>> Project].

Book[
	publisher =>> Organization;
	editor =>> Person;
	containsArticle =>> ArticleInBook].

TechnicalReport[
	series =>> STRING;
	number =>> NUMBER;
	organization =>> Organization].

JournalArticle[
	journal =>> Journal;
	firstPage =>> NUMBER;
	lastPage =>> NUMBER].

ArticleInBook[
	book =>> Book;
	firstPage =>> NUMBER;
	lastPage =>> NUMBER].

ConferencePaper[
	conference =>> Conference;
	proceedingsTitle =>> STRING;
	firstPage =>> NUMBER;
	lastPage =>> NUMBER].

WorkshopPaper[
	workshop =>> Workshop;
	proceedingsTitle =>> STRING;
	firstPage =>> NUMBER;
	lastPage =>> NUMBER].

Journal[
	editor =>> Person;
	publisher =>> Organization;
	volume =>> NUMBER;
	number =>> NUMBER;
	containsArticle =>> JournalArticle].

OnlinePublication[
	onlineVersionOf =>> Publication;
	type =>> STRING].


/*****
	Project
*****/

Project[
	title =>> STRING;
	member =>> Employee;
	head =>> Employee;
	isAbout =>> ResearchTopic;
	projectInfo =>> Publication;
	carriedOutBy =>> Organization;
	product =>> Product;
	financedBy =>> Organization].


/*****
	Event
*****/

Event[
	eventTitle =>> STRING;
	location =>> STRING;
	date =>> STRING;
	programCommittee =>> Person;
	orgCommittee =>> Person;
	publication =>> Publication;
	hasParts =>> Event;
	atEvent =>> Event].

Conference[
	series =>> STRING;
	number =>> NUMBER].

Workshop[
	series =>> STRING;
	number =>> NUMBER].


Meeting[
	participant =>> Person;
	date =>> STRING;
	title =>> STRING].


/*****
	ResearchTopic
*****/

ResearchTopic[
     Name		=>> STRING;
     Description	=>> STRING;
     Approaches		=>> STRING;
     ResearchGroups	=>> ResearchGroup;
     Researchers	=>> Researcher;
     RelatedTopics	=>> ResearchTopic;
     SubTopics		=>> ResearchTopic;
     Events		=>> Event;
     Journals		=>> Journal;
     Projects		=>> Project;
     ApplicationAreas	=>> STRING;
     Products		=>> Product;
     Bibliographies	=>> STRING;
     MailingLists	=>> STRING;
     Webpages		=>> STRING;
     InternationalFundingAgencies	=>> Organization;
     NationalFundingAgencies	=>> Organization;
     AuthorOfOntology		=>> Person;
     DateOfLastModification	=>> STRING
].

/*****
	Product
*****/

Product[
	producedBy =>> Project;
	developedBy =>> Organization].


/*****
	These inference rules copy values from one Root to
	another, i.e. defines the symmetric attributes.
*****/

FORALL O,C,A,V,T V:T <- C[A=>>T] AND O:C[A->>V].


/*****  Organization-Rules  *****/

FORALL Person1, Organization1
	Organization1:Organization[employs ->> Person1] <->
		Person1:Employee[affiliation ->> Organization1].

//Ist Person1 beim AIFB angestellt, dann auch an der Wiwi-Fakultät
//dann auch an der Uni-Ka usw.

        FORALL Person1, Organization1, Organization2
                Organization1:Organization[employs->>Person1] <-
                        Person1:Employee[affiliation ->> Organization2] AND
                        Organization1:Organization[hasParts->>Organization2].

FORALL Publication1, Organization1
	Organization1:Organization[publishes ->> Publication1] <->
		Publication1:Publication[publisher ->> Organization1].
// actually Publication should be union(Book, Journal)

FORALL TechnicalReport1, Organization1
	Organization1:Organization[technicalReport ->> TechnicalReport1] <->
		TechnicalReport1:TechnicalReport[organization ->> Organization1].

FORALL Organization1, Project1
	Organization1:Organization[carriesOut ->> Project1] <->
		Project1:Project[carriedOutBy ->> Organization1].

FORALL Organization1, Product1
	Organization1:Organization[develops ->> Product1] <->
		Product1:Product[developedBy ->> Organization1].

FORALL Person1, Group1
	Group1:ResearchGroup[member ->> Person1] <->
		Person1:Researcher[memberOf ->> Group1].

FORALL Employee1, Group1
        Employee1:Employee[headOfGroup ->> Group1] <->
                Group1:ResearchGroup[head ->> Employee1].


/*****  Person-Rules not allready listed above *****/

FORALL Person1, Person2
	Person1:Researcher[cooperatesWith ->> Person2] <-
		Person2:Researcher[cooperatesWith ->> Person1].

FORALL Person1, Publication1
	Publication1:Publication[author ->> Person1] <->
		Person1:Person[publication ->> Publication1].

FORALL Person1, Event1
	Event1:Event[orgCommittee ->> Person1] <->
		Person1:Person[organizerOrChairOf ->> Event1].

FORALL Person1, Event1
	Event1:Event[programCommittee ->> Person1] <->
		Person1:Person[memberOfPC ->> Event1].

FORALL Person1, Publication1
	Publication1:Publication[editor ->> Person1] <->
		Person1:Person[editor ->> Publication1].
//actually Publication should be union(book, journal)

FORALL Employee1, Project1
	Project1:Project[member ->> Employee1] <->
		Employee1:Employee[worksAtProject ->> Project1].

FORALL Employee1, Project1
	Project1:Project[head ->> Employee1] <->
		Employee1:Employee[headOf ->> Project1].

FORALL Person1, Person2
	Person1:PhDStudent[supervisor ->> Person2] <->
		Person2:AcademicStaff[supervises ->> Person1].

FORALL Person1, Topic1
	Topic1:ResearchTopic[Researchers ->> Person1] <->
		Person1:Researcher[researchInterest ->> Topic1].

FORALL Person1, University1
	University1:University[student ->> Person1] <->
		Person1:Student[studiesAt ->> University1].


/*****  Publication-Rules not allready listed above *****/

FORALL Publication1, Publication2
	Publication2:OnlinePublication[onlineVersionOf ->> Publication1] <->
		Publication1:Publication[onlineVersion ->> Publication2].

FORALL Publication1, Project1
	Project1:Project[projectInfo ->> Publication1] <->
		Publication1:Publication[describesProject ->> Project1].

FORALL Publication1, Publication2
	Publication2:Book[containsArticle ->> Publication1] <->
		Publication1:ArtcileInBook[book ->> Publication2].

FORALL Publication1, Publication2
	Publication2:Journal[containsArticle ->> Publication1] <->
		Publication1:JournalArticle[journal ->> Publication2].

FORALL Publication1, Event1
	Event1:Conference[publication ->> Publication1] <->
		Publication1:ConferencePaper[conference ->> Event1].
// publication in Conference is inherited

FORALL Publication1, Event1
	Event1:Workshop[publication ->> Publication1] <->
		Publication1:WorkshopPaper[workshop ->> Event1].
// publication in Workshop is inherited


/*****  Project-Rules not allready listed above *****/

FORALL Topic1, Project1
	Project1:Project[isAbout ->> Topic1] <->
		Topic1:ResearchTopic[Projects ->> Project1].

FORALL Product1, Project1
	Project1:Project[product ->> Product1] <->
		Product1:Product[producedBy ->> Project1].

FORALL Org1, Project1
	Project1:Project[financedBy ->> Org1] <->
		Org1:Organization[finances ->> Project1].


/*****  Event-Rules not allready listed above *****/

FORALL Event1, Event2
	Event1:Event[hasParts ->> Event2] <->
		Event2:Event[atEvent ->> Event1].